| Server IP : 51.89.169.208 / Your IP : 216.73.216.126 Web Server : Apache System : Linux ns3209505.ip-198-244-202.eu 4.18.0-553.27.1.el8_10.x86_64 #1 SMP Tue Nov 5 04:50:16 EST 2024 x86_64 User : yellowleaf ( 1019) PHP Version : 7.4.33 Disable Function : exec,passthru,shell_exec,system MySQL : OFF | cURL : ON | WGET : ON | Perl : ON | Python : ON | Sudo : ON | Pkexec : ON Directory : /usr/share/zsh/5.5.1/functions/ |
Upload File : |
#compdef nvram
local ret=1
local -a context line state state_descr tmp
local -A opt_args val_args
# Note: -x can only be used with -f/-p, but must be used first to have effect
_arguments -s : \
'(: -)-c[delete all NVRAM variables]' \
'(: -)-d[delete specified NVRAM variable]: :->variables-ro' \
'(: -)-f[set NVRAM variables from file]: :_files' \
'(: -)-p[print all NVRAM variables]' \
'(-c -d)-x[use XML format for input and output]' \
'(-)*: :->variables-rw' \
&& ret=0
[[ $state == variables-* ]] && {
tmp=( ${${(f)"$( command $service -p )"}%%[[:space:]]*} )
[[ $state == variables-rw ]] &&
tmp=( ${^tmp}'::NVRAM variable value' )
if (( $#tmp )); then
_values -w 'NVRAM variable' $tmp && ret=0
else
_message 'NVRAM variable' && ret=0
fi
}
return ret