| Server IP : 51.89.169.208 / Your IP : 216.73.216.211 Web Server : Apache System : Linux ns3209505.ip-198-244-202.eu 4.18.0-553.27.1.el8_10.x86_64 #1 SMP Tue Nov 5 04:50:16 EST 2024 x86_64 User : yellowleaf ( 1019) PHP Version : 7.4.33 Disable Function : exec,passthru,shell_exec,system MySQL : OFF | cURL : ON | WGET : ON | Perl : ON | Python : ON | Sudo : ON | Pkexec : ON Directory : /proc/self/root/usr/share/zsh/5.5.1/functions/ |
Upload File : |
#compdef mdfind
local ret=1
local -a context line state state_descr tmp
local -A opt_args val_args
_arguments -s -S : \
'(-count)-0[separate result paths by NUL]' \
'(-0)-count[display count of results instead of paths]' \
'(-literal)-interpret[interpret query as if entered in Spotlight search field]' \
'(-interpret)-literal[interpret query as literal query string]' \
'-live[provide live updates to query results]' \
'-onlyin[limit search to specified directory]: :_directories' \
'(: -s)*-name[search for files with names matching specified string]:file name string' \
'-reprint[reprint -live results on update]' \
'(: -name)-s[show contents of specified smart folder]: :->smart-folders' \
'(-s -name)1: :_guard "^-*" "query"' \
&& ret=0
[[ $state == smart-folders ]] && {
tmp=( "$HOME/Library/Saved Searches/"*.savedSearch(-.N:r:t) )
if (( $#tmp )); then
_values 'smart folder' $tmp && ret=0
else
_message 'smart folder' && ret=0
fi
}
return ret